Partiėle afgeleiden

>    restart:

Zi e: Stewart, § 14.1 - § 14.4. We beginnen met het laden van het pakket plots :

>    with(plots):

De grafieken in figuur 10 van § 14.1 van Stewart kunnen alsvolgt worden geproduceerd:

 

>    plot3d((x^2+3*y^2)*exp(-x^2-y^2),x=-3..3,y=-3..3);

[Maple Plot]

>    plot3d((x^2+3*y^2)*exp(-x^2-y^2),x=-3..3,y=-3..3,orientation=[145,120]);

[Maple Plot]

>    plot3d(sin(x)+sin(y),x=-5..5,y=-5..5);

[Maple Plot]

>    plot3d(sin(x)*sin(y)/(x*y),x=-10..10,y=-10..10);

[Maple Plot]

In voorbeeld 11 van § 14.1 worden de niveaukrommen  van de functie g(x,y) = sqrt(9-x^2-y^2)  bepaald resulterend in de contour map  in figuur 16. In Maple kan dit worden gedaan met behulp van het commando contourplot :

>    contourplot(sqrt(9-x^2-y^2),x=-4..4,y=-4..4);

[Maple Plot]

We kunnen echter ook gebruikmaken van het commando implicitplot  alsvolgt:

>    implicitplot({seq(x^2+y^2=9-k^2,k=0..3)},x=-4..4,y=-4..4,numpoints=10000);

[Maple Plot]

Als we nu proberen deze niveaukrommen op hoogte voor te stellen zodat ze een oppervlak vormen, dan krijgen we:

>    plot3d(sqrt(9-x^2-y^2),x=-4..4,y=-4..4,filledregions=true,style=contour);

[Maple Plot]

De grafiek van de functie in figuur 7 is:

>    plot3d(sqrt(9-x^2-y^2),x=-4..4,y=-4..4);

[Maple Plot]

Een functie f  van twee variabelen x  en y  kan alsvolgt worden gedefinieerd:

>    f := (x,y) -> -x*y*exp(-x^2-y^2);

f := (x, y) -> -x*y*exp(-x^2-y^2)

Vergelijk met figuur 19 van §  14.1:

>    contourplot(f(x,y),x=-2..2,y=-2..2);

[Maple Plot]

>    plot3d(f(x,y),x=-2..2,y=-2..2);

[Maple Plot]

De eerste partiėle afgeleiden  van f  zijn:

>    diff(f(x,y),x); diff(f(x,y),y);

-y*exp(-x^2-y^2)+2*x^2*y*exp(-x^2-y^2)

-x*exp(-x^2-y^2)+2*x*y^2*exp(-x^2-y^2)

Hier hebben we de expressie f(x,y)  respectievelijk gedifferentieerd naar de variabelen x  en y .

Als functies worden deze genoteerd als:

>    D[1](f); D[2](f);

(x, y) -> -y*exp(-x^2-y^2)+2*x^2*y*exp(-x^2-y^2)

(x, y) -> -x*exp(-x^2-y^2)+2*x*y^2*exp(-x^2-y^2)

Kijk nu eens naar voorbeeld 3 van §  14.3:

>    f := (x,y) -> sin(x/(1+y));

f := (x, y) -> sin(x/(1+y))

De eerste partiėle afgeleiden  zijn:

>    D[1](f); D[2](f);

(x, y) -> cos(x/(1+y))/(1+y)

(x, y) -> -cos(x/(1+y))*x/(1+y)^2

Voorbeeld 4 van § 14.3:

>    eq:=x^3+y^3+z^3+6*x*y*z=1;

eq := x^3+y^3+z^3+6*x*y*z = 1

Figuur 6:

>    implicitplot3d(eq,x=-2..2,y=-2..2,z=-2..2);

[Maple Plot]

De eerste partiėle afgeleiden  van z  naar de variabelen x  en y  zijn respectievelijk:

>    implicitdiff(eq,z,x);

>    implicitdiff(eq,z,y);

-(x^2+2*y*z)/(z^2+2*x*y)

-(y^2+2*x*z)/(z^2+2*x*y)

Voorbeeld 6 van § 14.3:

>    f := (x,y) -> x^3+x^2*y^3-2*y^2;

f := (x, y) -> x^3+x^2*y^3-2*y^2

De eerste partiėle afgeleiden  zijn:

>    D[1](f); D[2](f);

(x, y) -> 3*x^2+2*x*y^3

(x, y) -> 3*x^2*y^2-4*y

De tweede partiėle afgeleiden  zijn:

>    D[1,1](f); D[1,2](f); D[2,1](f); D[2,2](f);

(x, y) -> 6*x+2*y^3

(x, y) -> 6*x*y^2

(x, y) -> 6*x*y^2

(x, y) -> 6*x^2*y-4

Differentiėren we de expressie f(x,y)  dan krijgen we:

>    diff(f(x,y),x$2); diff(diff(f(x,y),x),y); diff(diff(f(x,y),x),y); diff(f(x,y),y$2);

6*x+2*y^3

6*x*y^2

6*x*y^2

6*x^2*y-4

Voorbeeld 7 van §  14.3:

>    f := (x,y,z) -> sin(3*x+y*z);

f := (x, y, z) -> sin(3*x+y*z)

>    D[1,1,2,3](f);

(x, y, z) -> 9*sin(3*x+y*z)*z*y-9*cos(3*x+y*z)

>    diff(diff(diff(f(x,y,z),x$2),y),z);

9*sin(3*x+y*z)*y*z-9*cos(3*x+y*z)

De stelling van Clairaut in § 14.3 stelt dat de gemengde tweede partiėle afgeleiden van een functie f  gelijk zijn in een punt (a,b) als beide functies continu zijn op een cirkelschijfje rond dat punt (a,b).

Blijkbaar neemt Maple aan dat dit altijd geldt:

>    restart: D[1,2](f)-D[2,1](f);

0

Voorbeeld 8 van  § 14.3:

>    u := (x,y) -> exp(x)*sin(y);

u := (x, y) -> exp(x)*sin(y)

>    diff(u(x,y),x$2)+diff(u(x,y),y$2);

0

Voorbeeld 9 van  § 14.3:

>    u := (x,t) -> sin(x-a*t);

u := (x, t) -> sin(x-a*t)

>    diff(u(x,t),t$2)-a^2*diff(u(x,t),x$2);

0

Voorbeeld 1 van  § 14.4:

>    f := (x,y) -> 2*x^2+y^2;

f := (x, y) -> 2*x^2+y^2

Het raakvlak  aan de grafiek van f  in het punt (1,1,3) is:

>    z = f(1,1)+D[1](f)(1,1)*(x-1)+D[2](f)(1,1)*(y-1);

z = -3+4*x+2*y

Figuur 2 kan nu alsvolgt worden geproduceerd:

>    with(plots): plot3d({2*x^2+y^2,4*x+2*y-3},x=-4..4,y=-4..4);

[Maple Plot]

>